Tinkering [Injection]

[MeSSiR 0]

Скрипт для прокачки тинкеринга с 33х до 120

 

# Create by MeSSiR
##################### MIDDLE-EARTH.RU ##########################
# Скрипт для прокачки скилла Tinkering.
# Работает по принципу изготовления необходимой вещи и
# последующием его перемещении в необходимый контейнер.
# Скрипт имеет 3 части, которая сама варьируется в зависимости
# от уровня навыка:
# 1) Изготовление Scorp (инструмент для разбора деревянных вещей)
# 2) Изготовление Tongs (инструмент для разбора вещей БСера). 
# 3) Изготовление BlankScrolls.
# Если вы хотите оставить изготавливаемые предметы, то при 
# запуске скрипта появившимся таргетом указывайте на контейнер
# рядом с вами на полу, но следите за тем, чтобы он не
# переполнился (149 итемов максимум). Если же вещи не нужны,
# то можете поставить рядом с собой мусорку (Trash) и указать
# таргетом на треш и тогда скрафченные вещи будут удаляться.
# При навыке Тинкера с 33 до 67 скрипт будет изготавливать
# Scorp(инструмент для разбора деревянных вещей обратно в логи)
# Для этого нужно положить в пак(!) побольше ингтов руды(любой)
# Вещи данного типа не стэкуются.
# При навыке Тинкера с 67 до 87 скрипт будет изготавливать
# Tongs(инструмент для разбора вещей БСера обратно в инги).
# Для этого нужно положить в пак(!) побольше ингтов руды(любой)
# Вещи данного типа не стэкуются.
# При навыке Тинкера с 87 до 120 скрипт будет изготавливать
# Blank Scrolls(пустые свитки для инскриптера). Для этого нужно
# положить возле себя на полу побольше дерева(простого).
# Вещи данного типа стэкуются, поэтому можно не переживать за.
# переполнение контейнера.
# Для работы скрипта необходимо:
# - Руду (до скилла 87) или дерево на полу(после скилла 87)
# - Инструмент тинкера (Tinkers Tools)
# Не забудьте, что после скилла в 100 необходимо использовать
# Lesser Power, Power, Greater Power и Ultimate скроллы.
# Желательно для скрипта:    
# - Еда
################################################################
###################### Настройка переменных ####################

var stop=120        # Стоп-отметка уровня скилла, когда нужно
                    # будет остановить прокачку для того, чтоб 
                    # применить Power скроллы. Если не нужна,
                    # то поставить значение 120.

var food='0x097B'        # Тип еды, которую будем кушать в процессе.
                    # '0x097B' - жаренная рыба
                    # '0x09F2' - жаренное мясо
                    # '0x171F' - бананы
                    

sub Tinkering()
var time=0
uo.deletejournal()
uo.set('finddistance','1')
UO.Print('Укажите контейнер на полу')
wait(100)
UO.Print('возле себя в который будем')
wait(100)
UO.Print('складывать сделанное:')
wait(100)
UO.Print('Если нужно удалять, то укажите на трешку.')
uo.AddObject('bag')
While uo.Targeting()
Wait(100)
Wend
uo.msg(".pray")
while uo.skillval('Tinkering',1) < 670
    checkitems()
    uo.waitmenu('Select','Tools','Select','Scorp')
    uo.waittargettype('0x1BF2')
    uo.usetype('0x1EBC')
    repeat
        wait(1000)
        time=time+1
    until uo.injournal("You create|You destroy|You make") or time > 20
    time=0
    uo.findtype('0x10E7')
    if uo.findcount() then
        uo.moveitem('finditem','1','bag')
        wait(500)
    endif
    uo.deletejournal()
wend
while uo.skillval('Tinkering',1) < 870
    checkitems()
    uo.waitmenu('Select','Tools','Select','Tongs')
    uo.waittargettype('0x1BF2')
    uo.usetype('0x1EBC')
    repeat
        wait(1000)
        time=time+1
    until uo.injournal("You create|You destroy|You make") or time > 20
    time=0
    uo.findtype('0x0FBB')
    if uo.findcount() then
        uo.moveitem('finditem','1','bag')
        wait(500)
    endif
    uo.deletejournal()
wend
while uo.skillval('Tinkering',1) < 1200
    checkitems()
    uo.findtype(0x1BDD)
    if uo.findcount()>1 then
        uo.moveitem('finditem','-1','backpack')
        wait(500)
    endif
    while uo.count(0x1BDD)<5
        uo.findtype('0x1BDD','-1','ground')
        if uo.findcount() then
            uo.moveitem('finditem','3','backpack')
            wait(500)
        endif
    wend
    uo.waitmenu('Select','Paper','Choose','Blank Scroll')
    uo.waittargettype('0x1BDD')
    uo.usetype('0x1EBC')
    repeat
        wait(1000)
        time=time+1
    until uo.injournal("You create|You destroy|You make") or time > 20
    time=0
    uo.findtype('0x0E34')
    if uo.findcount() then
        uo.moveitem('finditem','-1','bag')
        wait(500)
    endif
    uo.deletejournal()
wend
end sub

Sub checkitems()
uo.msg(".pray")
eda()
while uo.count('0x1EBC') < 1
    uo.print("Нет инструмента!")
    uo.msg("Не могу работать!")
    wait(5000)
wend
if uo.skillval('Tinkering',1) < 870 then
    while uo.count('0x1BF2') < 20
        uo.print("Нет инготов для работы!")
        uo.msg("Не могу работать!")
        wait(5000)
    wend
else
    repeat
    uo.findtype('0x1BDD','-1','ground')
    if NOT uo.findcount() then
        uo.print("Нет дерева на полу возле меня!")
        uo.msg("Не могу работать!")
        wait(5000)
    endif
    until uo.findcount()
endif
while uo.skillval('Tinkering',1) >= stop*10
    uo.msg("Стоп-отметка! Скилл прокачался до "+str(stop))
    wait(3000)
wend
end sub

Sub eda()
uo.findtype(food)
if uo.findcount() then
    uo.usetype(food)
else
    uo.print("Нет еды!")
endif
end sub